Просмотр исходного текста страницы Внешний интерфейс обработки - API v2

Функционал внешней обработки можно использовать  извне, то есть, не запуская саму обработку, а просто вызывая из нее определенные методы. Таким образом можно осуществлять формирование и предварительный просмотр пакета электронных документов, отправку документов, сопоставление электронных документов с документами 1С, утверждение документов, обработку служебных документов и обновление статусов.
=Подготовительные действия=
В большинстве случаев перед вызовом функций внешнего интерфейса обработки необходимо выполнить следующие подготовительные действия.

== Получаем внешнюю обработку ==

=== Обычное приложение из файла===

<source lang="1C">
ВО = ВнешниеОбработки.Создать("d:\ВнешняяОбработка2\Sbis1C.epf");
</source>
=== Обычное приложение из справочника 1С===
<source lang="1C">
ОбработкаСБИС = Справочники.ВнешниеОбработки.НайтиПоНаименованию("Электронный обмен документами в СБиС");
ДвоичныеДанные = ОбработкаСБИС.ХранилищеВнешнейОбработки.Получить();
ИмяОбработки = ПолучитьИмяВременногоФайла();
ДвоичныеДанные.Записать(ИмяОбработки);

ВО = ВнешниеОбработки.Создать(ИмяОбработки);
</source>
=== Управляемое приложение из файла===
<source lang="1C">
ВО = ВнешниеОбработки.Создать( "d:\ВнешняяОбработка2\Sbis1C_UF.epf", Ложь );
</source>
=== Управляемое приложение из справочника 1С===
<source lang="1C">
ОбработкаСБИС = Справочники.ДополнительныеОтчетыИОбработки.НайтиПоНаименованию("Отправить документ через online.sbis.ru");
ДвоичныеДанные = ОбработкаСБИС.ХранилищеОбработки.Получить();
ИмяОбработки = ПолучитьИмяВременногоФайла();
ДвоичныеДанные.Записать(ИмяОбработки);

ВО = ВнешниеОбработки.Создать(ИмяОбработки, Ложь);
</source>
В параметре БезопасныйРежим указываем Ложь.

== Получаем форму "Внешний интерфейс" ==


=== Обычное приложение ===

<source lang="1C">
ВИ = ВО.ПолучитьФорму("ВнешнийИнтерфейс");
</source>

=== Управляемое приложение ===

<source lang="1C">
ВИ = ПолучитьФорму("ВнешняяОбработка.СБИС.Форма.ВнешнийИнтерфейс");
</source>

== Вызываем функцию инициализации ==

Включает в себя подготовку кэша и чтение настроек
<source lang="1C">
Кэш = ВИ.сбисИнициализировать();
</source>


== Авторизуемся (в случае, если обмен идет через SDK или API) ==

<source lang="1C">
УспешнаяАвторизация = ВИ.сбисАвторизация(Кэш, ПараметрыАвторизации, ЗапускРоботом);
</source>
ПараметрыАвторизации - структура с полями:
* ИдентификаторСессии (не обязательное) - рекомендуется указывать идентификатор сессии предыдущего сеанса для ускорения работы. Если сессия истекла, то новый идентификатор можно взять из поля Кэш.Парам.ИдентификаторСессии после авторизации.
* ВходПоСертификату - Истина, если авторизуемся по сертификату, Ложь, если авторизуемся по логину/паролю.
* Сертификат - отпечаток сертификата для авторизации. Заполняется, если ВходПоСертификату = Истина.
* Логин - логин для автоиизации. Заполняется, если ВходПоСертификату = Ложь.
* Пароль - пароль для авторизации. Заполняется, если ВходПоСертификату = Ложь.

ЗапускРоботом (не обязательный) - булевская переменная, по умолчанию имеет значение Истина.
* Если будет передано значение Истина (или параметр будет проигнорирован) произойдет попытка авторизации по данным из структуры ПараметрыАвторизации. В случае неудачи вернет текст ошибки.
* Если будет передано значение Ложь произойдет попытка авторизации по переданным данным из ПараметрыАвторизации. В случае неудачи будет открыто окно авторизации, где пользователь сможет авторизоваться вручную.


=Отправка документов=
Для отправки документов из 1С в электронном виде без запуска внешней обработки необходимо лишь определиться, какие документы будем отправлять, и выполнить описанные ниже действия. 

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Вызываем функцию отправки документов
<source lang="1C">
Результат = ВИ.сбисОтправка(Кэш, СписокСтрок);
</source>
СписокСтрок – список значений. Каждое значение – структура с полем «СоставПакета». 

СоставПакета – список значений. Каждое значение может быть одним из двух типов:

*Ссылка на документ 1С. В представление можно записать название файла настроек для данного документа. Если не указано, то будет использован файл настроек, соответствующий имени документа в конфигураторе. Можно указывать только документы, для которых есть файл настроек. Если хотя бы для одного документа из состава пакета не будет файла настроек, то весь пакет не будет сформирован и отправлен.
*Строка с абсолютным путем к файлу (используется, если нужно отправить неформализованные вложения).

Первое вложение пакета должно быть ссылкой на документ 1С, т.к. по нему будут определяться отправитель и получатель пакета.

// Пример формирования списка документов для отправки
<source lang="1C">
СписокСтрок = Новый СписокЗначений;

СоставПакета = Новый СписокЗначений;

СоставПакета.Добавить(Документы.РеализацияТоваровУслуг.НайтиПоНомеру("00000000031", ТекущаяДата()));

СоставПакета.Добавить(Документы.СчетФактураВыданный.НайтиПоНомеру("000000000019", ТекущаяДата()));

СоставПакета.Добавить("C:\Документы\Соглашение с ООО Солнышко.doc");

СписокСтрок.Добавить(Новый Структура("СоставПакета",СоставПакета));

СоставПакета = Новый СписокЗначений;

СоставПакета.Добавить(Документы.РеализацияТоваровУслуг.НайтиПоНомеру("00000000032", ТекущаяДата()));

СписокСтрок.Добавить(Новый Структура("СоставПакета",СоставПакета));
</source>

Функция возвращает структуру с результатами отправки либо текст ошибки.

=Сопоставление документов=
Документы, полученные в электронном виде можно автоматически сопоставить с документами, которые уже заведены в 1С, не запуская внешнюю обработку. Для этого необходимо выполнить следующие действия:

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Заполняем параметры фильтра (не обязательно).
 
Фильтр - структура. Может содержать поля, одноименные полям фильтра на главном окне: ФильтрДатаНач, ФильтрДатаКнц, ФильтрОрганизация, ФильтрКонтрагент. По указанным параметрам будут запрашиваться документы с online.sbis.ru для сопоставления с документами в 1С.

3.	Вызываем функцию сопоставления
<source lang="1C">
Результат = ВИ.сбисСопоставление(Кэш, Фильтр);
</source>
Если Фильтр не заполнен, то передаем пустую структуру. В этом случае для сопоставления будут запрашиваться все документы, начиная с последней даты сопоставления по текущую дату. Последняя дата сопоставления записывается в файл сбисПараметры.xml в каталоге настроек.

Функция возвращает структуру с полем "СопоставленныеДокументы" либо текст ошибки.

СопоставленныеДокументы - массив структур. Каждая структура содержит Документ 1С, идентификаторы пакета, вложения и статус документа в СБИС.

=Утверждение документов=
Утверждение полученных документов также можно выполнить, не запуская обработку. Например, можно утвердить полученные документы, которые однозначно сопоставились с документами 1С.
Документы можно не только утвердить, но и выполнить любое другое действие, не требующее ввода комментария. 

Для утверждения документов выполняем следующие действия:

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Вызываем функцию выполнения команды
<source lang="1C">
Результат = ВИ.сбисВыполнитьКоманду(Кэш, МассивИд, ИмяКоманды);
</source>
МассивИд - массив, содержащий идентификаторы пакетов документов.

ИмяКоманды - название действия, которое необходимо выполнить с указанными пакетами, например, "Утвердить".

Результат - структура с полем РезультатВыполнения либо текст ошибки.

РезультатВыполнения - массив структур, содержащих идентификатор пакета и результат выполнения команды (Истина/Ложь).

=Обработка служебных документов=
Для обработки служебных документов выполняем следующие действия:

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Вызываем функцию обработки служебных
<source lang="1C">
Результат = ВИ.сбисОбработкаСлужебныхДокументов(Кэш);
</source>

В случае возникновения ошибки ее текст будет возвращен в Результат.

=Обновление статусов документов=
Для обновления статусов документов выполняем следующие действия:

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Вызываем функцию обновления статусов документов
<source lang="1C">
Результат = ВИ.сбисОбновлениеСтатусов(Кэш);
</source>

В случае возникновения ошибки ее текст будет возвращен в Результат.

=Перемещение документов между этапами=
Используется при необходимости указания исполнителя или комментария.
Для перемещения документа на следующий этап выполняем следующие действия:

1.	[[#Подготовительные действия|Подготовительные действия]]

2.	Вызываем функцию получения документа (заранее знаем его идентификатор Ид)
<source lang="1C">
Документ = Кэш.Интеграция.ПрочитатьДокумент(Кэш,Ид)
</source>

3.	Записываем действие которое собираемся выполнить для документа (какой переход будет сделан для документа)
<source lang="1C">
Действие = Новый Структура; 		                   	// Готовим Действие (переход с текущего этапа документооборота)
Для каждого Переход Из Документ.Этап[0].Действие Цикл 	        // Перебираем возможные переходы для документа
	Если Переход.Название = НазваниеНужногоДействия Тогда   // Ищем среди них такой переход который нам нужен
		Действие.Вставить("Состав",Переход);          	// Если находим добавляем в объект Действие
	КонецЕсли;
КонецЦикла
</source>

Если известно, что исполнитель следующего этапа назначается при выполнении, то мы можем указать его из учетной системы. Для этого нужно добавить объект Исполнитель в объект Действие

<source lang="1C">
Исполнитель = Новый Структура;
Исполнитель.Вставить("Имя","Глеб");
Исполнитель.Вставить("Фамилия","Никифоров");
Исполнитель.Вставить("Отчество","Станиславович");
Действие.Состав.Вставить("Исполнитель",Исполнитель);
</source>

4.     Выполняем действие (передвигаем документ на следующий этап)
<source lang="1C">
Этап = Документ.Этап[0];
Действие = Действие.Состав;
Комментарий = "Если обязателен для выполнения перехода, то нужно заполнить";
НазваниеПакета = "";
Кэш.Интеграция.сбисВыполнитьДействие(Кэш, Документ, Этап, Действие,Комментарий,НазваниеПакета);
</source>

=Открытие карточки электронного документа=
Данный механизм используется для открытия формы просмотра электронных документов из карточки документа 1С. Авторизация для данных методов происходит внутри Внешнего интерфейса и нет необходимости осуществлять ее перед их вызовом.

== Подготовка пакета к отправке и открытие его формы предпросмотра ==
В результате выполнения, будет сформирован пакет электронных документов и открыта форма его предпросмотра. Пакет сформируется на основе документа 1С (и по все связанным документам) из карточки которого происходил запуск механизма.
===Обычное приложение===
Для формирования пакета электронных документов и открытия окна предварительного просмотра необходимо выполнить следующие действия: 
# Получить внешнюю обработку
# Получить форму программного интерфейса обработки
# Выполнить метод
# Если метод вернул ошибку авторизации
## Вызвать метод авторизации
## Повторить вызов метода

1.	[[#Получаем внешнюю обработку|Получаем внешнюю обработку]]

2.	Вызываем функцию печати из обработки
<source lang="1C">
ВО.Печать(Документ1С);
</source>
Документ1С – ссылка на документ 1С. Можно передавать документы только определенных типов, для которых в каталоге настроек внешней обработки есть файлы настроек с параметром «ЗапросСпискаДокументов». В запросе определяется состав пакета документов, который будет сформирован и открыт для предварительного просмотра.
===Управляемое приложение===
Необходимо выполнить следующие действия:

1.	[[#Получаем внешнюю обработку|Получаем внешнюю обработку]] 

	Данный код выполняется на сервере. 

Следующие пункты выполняются на клиенте.

2.	Получаем форму главного окна
<source lang="1C">
ГлавноеОкно = ПолучитьФорму("ВнешняяОбработка.СБИС.Форма.ФормаГлавноеОкно");
</source>
3.	Вызываем функцию печати из главного окна
<source lang="1C">
ГлавноеОкно.Печать("", МассивДокументов);
</source>
	МассивДокументов – массив с одним элементом – ссылкой на документ 1С.

== Открыть форму просмотра электронного документа по идентификатору ==
Позволяет открыть форму просмотра электронного документа по идентификатору из доп.реквизитов документа 1С. Можно использовать для открытия загруженных/сопоставленных через ВО документов, а так же ранее отправленных. Иными словами любых документов у которых в доп.реквизитах есть идентификатор

=== Обычное приложение ===
1.	[[#Получаем внешнюю обработку|Получаем внешнюю обработку]]
 
2.	Получаем форму Внешнего интерфейса
<source lang="1C">
ВИ = ВО.ПолучитьФорму("ВнешнийИнтерфейс");
</source>
3.	Вызываем функцию инициализации для подготовки кэша и чтения настроек
<source lang="1C">
Кэш = ВИ.сбисИнициализировать();
</source>
4.	Вызываем функцию открытия документа по идентификатору.
<source lang="1C">
СсылкаНаОбъект = ЭтотОбъект.Ссылка;
Параметры = Новый Структура("Документ,Раздел", СсылкаНаОбъект, "1");
ВИ.сбисОткрытьДокументПоИдентификатору(Кэш, Параметры);
</source>
На вход подаем кэш и подготовленную структуру параметров, состоящую из ссылки на документ (получаем с текущей формы) и Раздела со значением «1» (необходимо для корректной отрисовки тулбара и видимости определенных элементов. По сути сообщаем, что открываем документ из раздела Полученные. Если механизм применяется для отправленных документов, то передаем «2»)

=== Управляемое приложение ===
1.	[[#Получаем внешнюю обработку|Получаем внешнюю обработку]]
 
2.	Получаем форму Внешнего интерфейса
<source lang="1C">
ВИ = ВО.ПолучитьФорму("ВнешнийИнтерфейс");
</source>
3.	Вызываем функцию инициализации для подготовки кэша и чтения настроек. В связи с особенностью управляемых формы мы должны хранить на форме пользователя (откуда происходит вызов) в сохраняемом реквизите формы идентификатор сессии. Поэтому при вызове функции инициализации передаем туда структуру с доп.параметром ИдентификаторСессии
<source lang="1C">
Кэш = ВИ.сбисИнициализировать(Новый Структура("ИдентификаторСессии", ИдентификаторСессии));
</source>
4.	Вызываем функцию открытия документа по идентификатору.
<source lang="1C">
СсылкаНаОбъект = ЭтотОбъект.Ссылка;
Параметры = Новый Структура("Документ,Раздел", СсылкаНаОбъект, "1");
ВИ.сбисОткрытьДокументПоИдентификатору(Кэш, Параметры);
</source>
На вход подаем кэш и подготовленную структуру параметров, состоящую из ссылки на документ (получаем с текущей формы) и Раздела со значением «1» (необходимо для корректной отрисовки тулбара и видимости определенных элементов. По сути сообщаем, что открываем документ из раздела Полученные. Если механизм применяется для отправленных документов, то передаем «2»)

5.	По завершению работы внешнего интерфейса необходимо обновить идентификатор сессии на форме, где он у вас хранится
<source lang="1C">
ИдентификаторСессии = Кэш.Парам.ИдентификаторСессии;
</source>
[[Категория:1С]]