Внешний интерфейс обработки - API

Функционал внешней обработки можно использовать извне, то есть, не запуская саму обработку, а просто вызывая из нее определенные методы. Таким образом можно осуществлять формирование и предварительный просмотр пакета электронных документов, отправку документов, сопоставление электронных документов с документами 1С, утверждение документов, обработку служебных документов и обновление статусов.

Подготовительные действия

В большинстве случаев перед вызовом функций внешнего интерфейса обработки необходимо выполнить следующие подготовительные действия.

1. Получаем внешнюю обработку

Обычное приложение

ВО = ВнешниеОбработки.Создать("d:\ВнешняяОбработка2\Sbis1C.epf");

Управляемое приложение

ВО = ВнешниеОбработки.Создать( "d:\ВнешняяОбработка2\Sbis1C_UF.epf", Ложь );

2. Получаем форму "Внешний интерфейс"

Обычное приложение

ВИ = ВО.ПолучитьФорму("ВнешнийИнтерфейс");

Управляемое приложение

ВИ = ПолучитьФорму("ВнешняяОбработка.СБИС.Форма.ВнешнийИнтерфейс");

3. Вызываем функцию подготовки кэша

Кэш = ВИ.сбисПодготовитьКэш();

4. Авторизуемся (в случае, если обмен идет через SDK или API)

УспешнаяАвторизация = ВИ.сбисАвторизация(Кэш, ПараметрыАвторизации);

ПараметрыАвторизации - структура с полями:

• ИдентификаторСессии (не обязательное) - рекомендуется указывать идентификатор сессии предыдущего сеанса для ускорения работы. Если сессия истекла, то новый идентификатор можно взять из поля Кэш.Парам.ИдентификаторСессии после авторизации.
• ВходПоСертификату - Истина, если автоизуемся по сертификату, Ложь, если авторизуемся по логину/паролю.
• Сертификат - отпечаток сертификата для автоизации.
• Логин - логин для автоиизации.
• Пароль - пароль для авторизации.

5. Читаем файлы настроек

ВИ.сбисПрочитатьНастройки(Кэш);

Отправка документов

Для отправки документов из 1С в электронном виде без запуска внешней обработки необходимо лишь определиться, какие документы будем отправлять, и выполнить описанные ниже действия.

1. Подготовительные действия

2. Вызываем функцию отправки документов

Результат = ВИ.сбисОтправка(Кэш, СписокСтрок);

СписокСтрок – список значений. Каждое значение – структура с полем «СоставПакета».

СоставПакета – список значений. Каждое значение может быть одним из двух типов:

• Ссылка на документ 1С. В представление можно записать название файла настроек для данного документа. Если не указано, то будет использован файл настроек, соответствующий имени документа в конфигураторе. Можно указывать только документы, для которых есть файл настроек. Если хотя бы для одного документа из состава пакета не будет файла настроек, то весь пакет не будет сформирован и отправлен.
• Строка с абсолютным путем к файлу (используется, если нужно отправить неформализованные вложения).

Первое вложение пакета должно быть ссылкой на документ 1С, т.к. по нему будут определяться отправитель и получатель пакета.

// Пример формирования списка документов для отправки

СписокСтрок = Новый СписокЗначений;

СоставПакета = Новый СписокЗначений;

СоставПакета.Добавить(Документы.РеализацияТоваровУслуг.НайтиПоНомеру("00000000031", ТекущаяДата()));

СоставПакета.Добавить(Документы.СчетФактураВыданный.НайтиПоНомеру("000000000019", ТекущаяДата()));

СоставПакета.Добавить("C:\Документы\Соглашение с ООО Солнышко.doc");

СписокСтрок.Добавить(Новый Структура("СоставПакета",СоставПакета));

СоставПакета = Новый СписокЗначений;

СоставПакета.Добавить(Документы.РеализацияТоваровУслуг.НайтиПоНомеру("00000000032", ТекущаяДата()));

СписокСтрок.Добавить(Новый Структура("СоставПакета",СоставПакета));

Функция возвращает структуру с результатами отправки либо текст ошибки.

Сопоставление документов

Документы, полученные в электронном виде можно автоматически сопоставить с документами, которые уже заведены в 1С, не запуская внешнюю обработку. Для этого необходимо выполнить следующие действия:

1. Подготовительные действия

2. Заполняем параметры фильтра (не обязательно).

Фильтр - структура. Может содержать поля, одноименные полям фильтра на главном окне: ФильтрДатаНач, ФильтрДатаКнц, ФильтрОрганизация, ФильтрКонтрагент. По указанным параметрам будут запрашиваться документы с online.sbis.ru для сопоставления с документами в 1С.

3. Вызываем функцию сопоставления

Результат = ВИ.сбисСопоставление(Кэш, Фильтр);

Если Фильтр не заполнен, то передаем пустую структуру. В этом случае для сопоставления будут запрашиваться все документы, начиная с последней даты сопоставления по текущую дату. Последняя дата сопоставления записывается в файл сбисПараметры.xml в каталоге настроек.

Функция возвращает структуру с полем "СопоставленныеДокументы" либо текст ошибки.

СопоставленныеДокументы - массив структур. Каждая структура содержит Документ 1С, идентификаторы пакета, вложения и статус документа в СБИС.

Утверждение документов

Утверждение полученных документов также можно выполнить, не запуская обработку. Например, можно утвердить полученные документы, которые однозначно сопоставились с документами 1С. Документы можно не только утвердить, но и выполнить любое другое действие, не требующее ввода комментария.

Для утверждения документов выполняем следующие действия:

1. Подготовительные действия

2. Вызываем функцию выполнения команды

Результат = ВИ.сбисВыполнитьКоманду(Кэш, МассивИд, ИмяКоманды);

МассивИд - массив, содержащий идентификаторы пакетов документов.

ИмяКоманды - название действия, которое необходимо выполнить с указанными пакетами, например, "Утвердить".

Результат - структура с полем РезультатВыполнения либо текст ошибки.

РезультатВыполнения - массив структур, содержащих идентификатор пакета и результат выполнения команды (Истина/Ложь).

Обработка служебных документов

Для обработки служебных документов выполняем следующие действия:

1. Подготовительные действия

2. Вызываем функцию обработки служебных

Результат = ВИ.сбисОбработкаСлужебныхДокументов(Кэш);

В случае возникновения ошибки ее текст будет возвращен в Результат.

Обновление статусов документов

Для обновления статусов документов выполняем следующие действия:

1. Подготовительные действия

2. Вызываем функцию обновления статусов документов

Результат = ВИ.сбисОбновлениеСтатусов(Кэш);

В случае возникновения ошибки ее текст будет возвращен в Результат.

Перемещение документов между этапами

Используется при необходимости указания исполнителя или комментария. Для перемещения документа на следующий этап выполняем следующие действия:

1. Подготовительные действия

2. Вызываем функцию получения документа (заранее знаем его идентификатор Ид)

Документ = Кэш.Интеграция.ПрочитатьДокумент(Кэш,Ид)

3. Записываем действие которое собираемся выполнить для документа (какой переход будет сделан для документа)

Действие = Новый Структура; 		                   	// Готовим Действие (переход с текущего этапа документооборота)
Для каждого Переход Из Документ.Этап[0].Действие Цикл 	        // Перебираем возможные переходы для документа
	Если Переход.Название = НазваниеНужногоДействия Тогда   // Ищем среди них такой переход который нам нужен
		Действие.Вставить("Состав",Переход);          	// Если находим добавляем в объект Действие
	КонецЕсли;
КонецЦикла

Если известно, что исполнитель следующего этапа назначается при выполнении, то мы можем указать его из учетной системы. Для этого нужно добавить объект Исполнитель в объект Действие

Исполнитель = Новый Структура;
Исполнитель.Вставить("Имя","Глеб");
Исполнитель.Вставить("Фамилия","Никифоров");
Исполнитель.Вставить("Отчество","Станиславович");
Действие.Состав.Вставить("Исполнитель",Исполнитель);

4. Выполняем действие (передвигаем документ на следующий этап)

Этап = Документ.Этап[0];
Действие = Действие.Состав;
Комментарий = "Если обязателен для выполнения перехода, то нужно заполнить";
НазваниеПакета = "";
Кэш.Интеграция.сбисВыполнитьДействие(Кэш, Документ, Этап, Действие,Комментарий,НазваниеПакета);

Открытие карточки электронного документа

Данный механизм используется при отправке документов непосредственно из карточки документа 1С по кнопке «Печать».

Обычное приложение

Для формирования пакета электронных документов и открытия окна предварительного просмотра необходимо выполнить следующие действия:

1. Получаем внешнюю обработку

ВО = ВнешниеОбработки.Создать("d:\user\bronfeld\ВнешняяОбработка2\Sbis1C.epf");

2. Вызываем функцию печати из обработки

ВО.Печать(Документ1С);

Документ1С – ссылка на документ 1С. Можно передавать документы только определенных типов, для которых в каталоге настроек внешней обработки есть файлы настроек с параметром «ЗапросСпискаДокументов». В запросе определяется состав пакета документов, который будет сформирован и открыт для предварительного просмотра.

Управляемое приложение

Необходимо выполнить следующие действия:

1. Получаем внешнюю обработку

ВО = ВнешниеОбработки.Создать("d:\user\bronfeld\ВнешняяОбработка2\Sbis1C_UF.epf", Ложь);

В параметре БезопасныйРежим указываем Ложь.

Данный код выполняется на сервере.

Следующие пункты выполняются на клиенте.

2. Получаем форму главного окна

ГлавноеОкно = ПолучитьФорму("ВнешняяОбработка.СБИС.Форма.ФормаГлавноеОкно");

3. Вызываем функцию печати из главного окна

ГлавноеОкно.Печать("", МассивДокументов);

МассивДокументов – массив с одним элементом – ссылкой на документ 1С.